Arduinoを使って距離と時間データをSDカードに記録しました

Table of Contents

この記事で学習できること

超音波距離センサ、RTC(実時間)モジュール、SDモジュールをArduino UNO R3に接続しデータの取得、時間計測、データ保存および距離によるLEDの点灯を一連の操作で実施する方法を学習します。

超音波距離センサ、RTCモジュール、SDモジュールの操作

超音波距離センサ、RTC(実時間)モジュール、SDモジュールを個別に操作する方法は学習しています。

(参考) 関連する記事

必要な部品は?

RTC(実時間)モジュール(DS1307)	1個
SDモジュール (microSDカードスロット)	1個
超音波センサモジュール (HC-SR04)	1個
LED 赤色	1個
LED 緑色	1個
抵抗（220Ω）	2個
抵抗 (1KΩ)	1個
タクトスイッチ	1個
Arduino UNO R3	1個

回路図

部品点数が多いのでFritzingで配線図を書くと見難くなるので見づらくなるのでKiCADで回路図を書きました。

(参考) 関連する記事は?

KiCADの入手方法と学習方法

実際の配線

部品をブレッドボード上に接続しました

完成品の動作の仕様

距離が50cm以内に反射物を検出すると、緑のLEDを点灯します。(5秒以上検出しないと消灯します。)
緑のLEDが点灯状態で50cm以内の反射物を10回以上検出しすると赤のLEDを点灯します。
RESET SWを押すと、緑と赤のLEDを消灯します。(赤のLEDはRESET SWで消灯できます。)
検出の状態を1秒間隔でSDカードに記録します。

SDカードには下記のデータをCSVファイルで記録します。

スケッチに使用するライブラリの入手先

スケッチで使用する、RTC(実時間)モジュール用ライブラリ(DS3231.h、DS3231.cpp)は[GitHub – jarzebski/Arduino-DS3231: DS3231 Real-Time-Clock]から取得しインストールしてください。
Arduno用のDS3231用のライブラリは何種類かが公開されていますが、この記事で使用しているライブラリは上記のライブラりであり、異なるライブラリを使用するとコンパイル時にエラーが発生します。

Arduino IDEにGitHubから取得したライブラリをインストールする方法

GitHubでライブラリをダウンロードする
- 対象ライブラリのGitHubページを開く
- 緑色の Code ボタンをクリック (リストの右上にある[<>Code▼]のボタンです。)
- Download ZIP を選択
- ZIPファイルがPCに保存される
- ※「Source code (zip)」でもOKですが、基本は上の手順で問題ありません。
Arduino IDEにZIPライブラリをインストールする (Arduino IDE 1.x / 2.x 共通)
- Arduino IDE を起動
- メニューから
- スケッチ → ライブラリをインクルード → .ZIP形式のライブラリをインストール
先ほどダウンロードした ZIP ファイルを選択
- IDE が自動的に展開してインストール完了
インストール確認
- メニューのスケッチ → ライブラリをインクルード
- 一覧の「インストール済み」セクションにライブラリ名が表示されていれば成功
注意点（特にGitHub系でよくある）
- ZIPの中にさらにフォルダ階層があるとIDEが認識しないことがある
  → libraryname/libraryname/*.h のように二重構造になっていないか確認
- src フォルダがあるタイプはそのままでOK
- リリースページに「Arduino用に整えたZIP」がある場合はそちらを使うと確実

RTC(実時間)モジュールに時刻を書き込みます

データロガーシールドのRTC(実時間)モジュールの時間はバッテリーを入れるだけでは不定の時間になっています。スケッチをコンパイルした時刻をRTC(実時間)モジュールに書き込みます。

RTC(実時間)モジュールに時刻を書き込むスケッチ

////////////////////////////////////////////////////////
// RTC(実時間)モジュールの時間設定を行い、時間を画面へ表示する
////////////////////////////////////////////////////////

//ライブラリインクルード
#include <Wire.h>
#include <DS3231.h>

//実時間モジュール設定
DS3231 clock;
RTCDateTime dt;

//一般変数
int i;

void setup()
{
  Serial.begin(9600);

  //実時間モジュールの初期化
  Serial.println("Initialize RTC module");
  // Initialize DS3231
  clock.begin();

  // スケッチのコンパイル時の時刻をRTCモジュールに書き込む
  clock.setDateTime(__DATE__, __TIME__);  

  dt = clock.getDateTime();

  //一般変数の初期化
  i=0;
  
  delay(1000);  
  
  //シリアルログの最初の行に表示項目を表示する
  Serial.print("Count,");    
  Serial.print("Year,");
  Serial.print("Month,");
  Serial.print("Day,");
  Serial.print("Hour,");
  Serial.print("Minuts,");
  Serial.println("Second,");
   
}

void loop()
{
  //シリアルログの表示
  dt = clock.getDateTime();
  Serial.print(i);   Serial.print(",");  
  Serial.print(dt.year);   Serial.print(",");
  Serial.print(dt.month);  Serial.print(",");
  Serial.print(dt.day);    Serial.print(",");
  Serial.print(dt.hour);   Serial.print(",");
  Serial.print(dt.minute); Serial.print(",");
  Serial.println(dt.second); 

  i+=1; //iに1を加える
  
  delay(1000);   // 1秒の待ち時間
}

全ての部品を操作するスケッチ

距離と時間データをSDカードに記録するスケッチ

//www.arduinomakesiteasy.com
//2022.5.4
//
// 1) Elegoo 実時間モジュール DS1307
// 2) Elegoo 超音波距離センサ HC-SR04
// 3) 秋田通商 SDモジュール
//

//ライブラリインクルード
#include <Wire.h>
#include <DS3231.h>
#include "SR04.h"
#include "SPI.h" 
#include "SD.h"

//SDカード設定
File myFile;                //クラス指定
const int chipSelect = 10;  //チップセレクトピン指定

//超音波距離センサ設定
#define TRIG_PIN 7
#define ECHO_PIN 6
SR04 sr04 = SR04(ECHO_PIN,TRIG_PIN);
int USdistance;

//実時間モジュール設定
DS3231 clock;
RTCDateTime dt;

//LED設定
#define DetectLED 3
#define FoundLED 5
const int DetectDistance=50;

//RESET
#define ResetSW 2

//一般変数
int i,j,k,val;

//ファイル作成・更新時のタイムスタンプを記録するスケッチ------------------------------
char timestamp[30];

// call back for file timestamps
void dateTime(uint16_t *date, uint16_t *time) {
 sprintf(timestamp, "%02d:%02d:%02d %2d/%2d/%2d \n",dt.hour,dt.minute,dt.second,dt.month,dt.day,dt.year-2000);
 // return date using FAT_DATE macro to format fields
 *date = FAT_DATE(dt.year,dt.month,dt.day);
 // return time using FAT_TIME macro to format fields
 *time = FAT_TIME(dt.hour,dt.minute,dt.second);
}
//------------------------------------------------------------------------------

void setup()
{
  Serial.begin(9600);

  //実時間モジュールの初期化
  Serial.println("Initialize RTC module");
  // Initialize DS3231
  clock.begin();
 
  //スケッチのコンパイル時の時刻をRTCモジュールに書き込む
  //1回目はこのままコンパイル実行する、
  //2回目にコメントアウトして再度コンパイル実行する
  //clock.setDateTime(__DATE__, __TIME__);    

  //SDカードの初期化
  Serial.println("Initializing SD card...");
  
  if (!SD.begin(chipSelect)) {
    Serial.println("Initialization failed or does not exist");
    while (1);
  }
  Serial.println("Initialization done.");
  Serial.println();

  //ファイル作成・更新時のタイムスタンプを記録するスケッチ------------------------------
  SdFile::dateTimeCallback(dateTime);
  sprintf(timestamp, "%02d:%02d:%02d %2d/%2d/%2d \n",dt.hour,dt.minute,dt.second,dt.month,dt.day,dt.year-2000);
  //------------------------------------------------------------------------------

  //LED初期化
  pinMode(DetectLED, OUTPUT);
  pinMode(FoundLED, OUTPUT);
  digitalWrite(DetectLED, LOW);
  digitalWrite(FoundLED, LOW);

  //ResetSW初期化
  pinMode(ResetSW, INPUT);

  //一般変数の初期化
  i=0;
  j=0;
  k=0;  
  val=0;
  
  delay(1000);  
  
  //シリアルログの最初の行に表示項目を表示する
  Serial.print("Year,");
  Serial.print("Month,");
  Serial.print("Day,");
  Serial.print("Hour,");
  Serial.print("Minuts,");
  Serial.print("Second,");
  Serial.print("Distance(cm),");  
  Serial.print("Detect Flag#1,");  
  Serial.println("Detect Flag#2");  

  //ログデータの最初の行に記録項目を記入する
  myFile = SD.open("DATA_LOG.csv", FILE_WRITE); //SDカードをオープンする 
  myFile.print("Year,");
  myFile.print("Month,");
  myFile.print("Day,");
  myFile.print("Hour,");
  myFile.print("Minuts,");
  myFile.print("Second,");
  myFile.print("Distance(cm),");   
  myFile.print("Detect Flag#1,");   
  myFile.println("Detect Flag#2");     
  myFile.close(); 	//SDカードをクローズする   
}

void loop()
{
  //シリアルログの表示
  dt = clock.getDateTime();
  Serial.print(dt.year);   Serial.print(",");
  Serial.print(dt.month);  Serial.print(",");
  Serial.print(dt.day);    Serial.print(",");
  Serial.print(dt.hour);   Serial.print(",");
  Serial.print(dt.minute); Serial.print(",");
  Serial.print(dt.second); Serial.print(",");
    
  USdistance=sr04.Distance();
  Serial.print(USdistance); Serial.print(",");  
  Serial.print(i); Serial.print(",");  
  Serial.println(k);  
   
  //SDカードへの書き込み
  myFile = SD.open("DATA_LOG.csv", FILE_WRITE); 

  myFile.print(dt.year);   myFile.print(",");
  myFile.print(dt.month);  myFile.print(",");
  myFile.print(dt.day);    myFile.print(",");
  myFile.print(dt.hour);   myFile.print(",");
  myFile.print(dt.minute); myFile.print(",");
  myFile.print(dt.second); myFile.print(",");
  myFile.print(USdistance);myFile.print(","); 
  myFile.print(i); myFile.print(",");
  myFile.println(k);

  myFile.close();

  //検出距離がDetectDistanceより小さな場合の処理
  if (USdistance <DetectDistance && k==0) {i+=1; digitalWrite(DetectLED, HIGH);}
  if (i >0 && k==0) {j+=1;}
  if (j-i>5 && k==0) { i=0; j=0; digitalWrite(DetectLED, LOW);}
  if (i>10 && k==0) { k=1; digitalWrite(FoundLED, HIGH);}

  //RsetSWが押された場合
  val=digitalRead(ResetSW);
  if (val==0) {
    i=0;
    j=0;
    k=0;
    digitalWrite(DetectLED, LOW);
    digitalWrite(FoundLED, LOW);
    }    
 
  delay(1000);  // 1秒間待つ 
}