Arduinoに接続したGPS受信機の測位データをSDカードに記録しました。

//----------------------------------------------
//https://arduinomakesiteasy.com/
//----------------------------------------------

#include <SoftwareSerial.h>
#include <TimeLib.h>
#include <SPI.h>
#include <SD.h>
#include <Wire.h>
#include <DS3231.h>

//SoftwareSerial 
SoftwareSerial myGPSSerial(2,3); //rx=2 tx=3

//RTC(実時間) module
DS3231 clock;
RTCDateTime dt;

//SD module
const int chipSelect = 10;  //SDカードCS
File logFile;
char fileName[16];
int fileNum = 0;

//TimeStamp matrix (ファイル作成時のタイムスタンプ)
char timestamp[30];

//Variables
String GPSString;

//----------------------------------------------
//setup()
//----------------------------------------------
 
void setup(){
  Serial.begin(9600); //シリアルモニタの開始
  delay(500); //待ち時間 0.5秒 
  init_RTC(); //RTC初期化  
  init_GPS(); //GPS初期化
  init_SD();  //SDカード初期化
}

//----------------------------------------------
//loop()
//----------------------------------------------
 
void loop(){

  //実時間取得
  dt = clock.getDateTime();
  
  // ソフトウェアシリアルのデータは改行まで取り込みSDカードに保存する
  if (myGPSSerial.available()){
        GPSString = myGPSSerial.readStringUntil('\n');
        Serial.println(GPSString.c_str());

        logFile = SD.open(fileName, FILE_WRITE);
        logFile.write(GPSString.c_str()); 
        logFile.close();    
  }

  // ソフトウェアシリアルのデータがオーバーフローしている場合はメッセージを出す
  if (myGPSSerial.overflow()) {
      Serial.println("myGPSSerial overflow!");
  }    
}

//----------------------------------------------
//RTCの初期化
//----------------------------------------------

void init_RTC(void){

  Serial.print("RTC Start ---> ");

  // Initialize DS3231
  clock.begin();
 
  //スケッチのコンパイル時の時刻をRTCモジュールに書き込む
  //1回目はこのままコンパイル実行する、
  //2回目にコメントアウトして再度コンパイル実行する
  clock.setDateTime(__DATE__, __TIME__);    

  Serial.println("Done");
 
}

//----------------------------------------------
//GPSの初期化
//----------------------------------------------

void init_GPS(void){
  
  Serial.print("GPS Start ---> ");
   
  myGPSSerial.begin(9600); //GPSと通信開始、GPSデフォルトの通信レート9600

  //GPSモジュールの設定を行う。一回実行すればGPSモジュールに設定は残るので、コメントアウトして再度書き込めば良い。
  //myGPSSerial.print("$PMTK314,0,5,0,5,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0*28\r\n"); //$GGA、RMCのみ5秒間隔で送信
  //myGPSSerial.print("$PMTK314,-1*04\r\n"); //設定値のリセット
    
  myGPSSerial.print("$PMTK314,0,0,0,2,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0*2A\r\n"); //$GGAのみ2秒間隔で送信

  //GPSモジュールのの設定後にGPSモジュールから返信があることを確認する
  while(!myGPSSerial.available()){
    delay(500);
  }

  //GGPSモジュールからの返信をバッファから除去する
  GPSString = myGPSSerial.readStringUntil('\n');
  
  Serial.println("Done");
}

//----------------------------------------------
//SDカード初期化とログファイル作成、タイムスタンプ設定
//----------------------------------------------

void init_SD(void){//SDカード初期化とログファイル作成、タイムスタンプ設定
  
  Serial.print("SD Start ---> ");
  
  while (!SD.begin(chipSelect)) {
    Serial.println("Failed during starting");
    //won't do anything later
    return;
  }
  Serial.println("Done");

  //ファイル作成・更新時のタイムスタンプを記録するスケッチ------------------------------
  SdFile::dateTimeCallback(dateTime);
  sprintf(timestamp, "%02d:%02d:%02d %2d/%2d/%2d \n",dt.hour,dt.minute,dt.second,dt.month,dt.day,dt.year-2000);
  //------------------------------------------------------------------------------

  boolean fileexist = false;
  String t;
  
  //既存のファイルのファイル名と重複しなければファイル名とする
  while(!fileexist){
    t = "GPS";
    if (fileNum < 10){
      t += "00";
    }
    else if(fileNum < 100){
      t += "0";
    }
    t += fileNum;
    t += ".LOG";
    t.toCharArray(fileName, 16);
    if(!SD.exists(fileName)) {
      fileexist = true;
    }
    fileNum++;
  }
  
  // ログファイルの1行目に”GPS NMEA Data ......”と書き込む
  logFile=SD.open(fileName, FILE_WRITE);
  logFile.println("GPS NMEA Data ......");
  logFile.close();
}

//----------------------------------------------
//call back for file timestamps
//----------------------------------------------

void dateTime(uint16_t *date, uint16_t *time) {
 sprintf(timestamp, "%02d:%02d:%02d %2d/%2d/%2d \n",dt.hour,dt.minute,dt.second,dt.month,dt.day,dt.year-2000);
 *date = FAT_DATE(dt.year,dt.month,dt.day); // return date using FAT_DATE macro to format fields
 *time = FAT_TIME(dt.hour,dt.minute,dt.second); // return time using FAT_TIME macro to format fields
}

#include <TimeLib.h>
#include <Wire.h>
#include <DS3231.h>

//RTC(実時間) module
DS3231 clock;
RTCDateTime dt;

  //ファイル作成・更新時のタイムスタンプを記録するスケッチ------------------------------
  SdFile::dateTimeCallback(dateTime);
  sprintf(timestamp, "%02d:%02d:%02d %2d/%2d/%2d \n",dt.hour,dt.minute,dt.second,dt.month,dt.day,dt.year-2000);
  //------------------------------------------------------------------------------

//----------------------------------------------
//call back for file timestamps
//----------------------------------------------

void dateTime(uint16_t *date, uint16_t *time) {
 sprintf(timestamp, "%02d:%02d:%02d %2d/%2d/%2d \n",dt.hour,dt.minute,dt.second,dt.month,dt.day,dt.year-2000);
 *date = FAT_DATE(dt.year,dt.month,dt.day); // return date using FAT_DATE macro to format fields
 *time = FAT_TIME(dt.hour,dt.minute,dt.second); // return time using FAT_TIME macro to format fields
}

  //実時間取得
  dt = clock.getDateTime();

  clock.setDateTime(__DATE__, __TIME__);